{
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-20.09";
  inputs.nixpkgs-unstable.url = "github:NixOS/nixpkgs/nixos-unstable";
  inputs.nixos-hardware.url = github:NixOS/nixos-hardware/master;

  # TODO: Remove nix overlay when pull request is resolved:
  # https://github.com/NixOS/nix/pull/4566
  inputs.nix.url = "github:orbekk/nix/master";
  inputs.nix.inputs.nixpkgs.follows = "nixpkgs";

  outputs = { self, nixpkgs, nixpkgs-unstable, nix, nixos-hardware }:
    {
      nixosConfigurations = let
        mkConfig = { hostName
                   , module ? (./. + "/machines/${hostName}.nix")
                   , system ? "x86_64-linux" }: {
          name = hostName;
          value = nixpkgs.lib.nixosSystem {
            system = "x86_64-linux";
            modules =
              [
                module
                nixpkgs.nixosModules.notDetected
                ({config, pkgs, ...}: {
                  # Let 'nixos-version --json' know about the Git revision
                  # of this flake.
                  system.configurationRevision =
                    if self ? rev then self.rev else "DIRTY";

                  nixpkgs.overlays = [
                    # Add unstable packages.
                    (final: prev: {
                      my-extras = {
                        inherit nixpkgs;
                        inherit nixpkgs-unstable;
                        inherit nixos-hardware;
                      };
                    })
                    # For git+file support with bare repo.
                    nix.overlay
                    (final: prev: { nixFlakes = final.nix; })
                  ];
                })
              ];
          };
        };
        myMachines = [
          { hostName = "pincer"; module = ./machines/x1-pincer.nix; }
          { hostName = "dragon"; }
          { hostName = "firelink"; }
        ];
      in builtins.listToAttrs (map mkConfig myMachines);
    };
}