{
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-23.05";
  inputs.nixpkgs-unstable.url = "github:NixOS/nixpkgs/nixos-unstable";
  inputs.nixos-hardware.url = "github:NixOS/nixos-hardware/master";
  inputs.emacs-overlay.url = "github:nix-community/emacs-overlay";
  inputs.agenix.url = "github:ryantm/agenix";
  inputs.agenix.inputs.nixpkgs.follows = "nixpkgs";
  inputs.jovian.url = "github:Jovian-Experiments/Jovian-NixOS";
  inputs.mujmap.url = "github:elizagamedev/mujmap";

  outputs =
    { self, nixpkgs, nixpkgs-unstable, nixos-hardware, emacs-overlay, agenix, jovian, mujmap }:
    let
      pkgs-module = { config, ... }:
      let
        cfg = config.nixpkgs;

        extra-packages = final: prev: {
          agenix = agenix.packages.${final.system}.default;
          mujmap = mujmap.packages.${final.system}.default;
        };

        unstable-overlay = final: prev: rec {
          unstable = import nixpkgs-unstable {
            inherit (cfg) config localSystem crossSystem;
          };
        };
      in {
        nixpkgs.pkgs = import nixpkgs {
          inherit (cfg) config localSystem crossSystem;
          overlays = cfg.overlays
          ++ [ unstable-overlay extra-packages emacs-overlay.overlay ];
        };
      };

      registry-module = { ... }: {
        nix.registry.nixpkgs.flake = nixpkgs;
        nix.registry.nixpkgs-unstable.flake = nixpkgs-unstable;
      };

      lib = nixpkgs.lib;

      orbekk-modules = let
        moduleFiles = lib.attrNames
        (lib.filterAttrs (n: v: lib.hasSuffix ".nix" n && v == "regular")
        (builtins.readDir ./modules));

        moduleNames = map (lib.removeSuffix ".nix") moduleFiles;

        mkModule = name: {
          inherit name;
          value = import (./. + "/modules/${name}.nix");
        };
      in lib.listToAttrs (map mkModule moduleNames);

    in {
      nixosModules = orbekk-modules // { inherit pkgs-module registry-module; };

      packages."x86_64-linux" =
        let pkgs = import nixpkgs { system = "x86_64-linux"; };
        in { };

        nixosConfigurations = let
          mkConfig = { hostName, module ? (./. + "/machines/${hostName}.nix")
          , system ? "x86_64-linux" }: {
            name = hostName;
            value = lib.nixosSystem {
              inherit system;

              modules = (lib.attrValues self.nixosModules) ++ [
                registry-module
                module
                nixpkgs.nixosModules.notDetected
                agenix.nixosModules.default
                ({ config, pkgs, ... }: {
                  # Let 'nixos-version --json' know about the Git revision
                  # of this flake.
                  system.configurationRevision = let
                    lastModified = pkgs.lib.substring 0 8
                    (self.lastModifiedDate or self.lastModified or "19700101");
                  in "${lastModified}.${self.shortRev or "dirty"}";
                })
              ] ++ lib.optional (hostName == "dex") jovian.nixosModules.jovian;
            };
          };
          myMachines = [
            {
              hostName = "pincer";
              module = ./machines/x1-pincer.nix;
            }
            { hostName = "dragon"; }
            { hostName = "firelink"; }
            { hostName = "tiny1"; }
            { hostName = "dex"; }
          ];
        in builtins.listToAttrs (map mkConfig myMachines);
    };
}